Obiekt typu Recordset przechowuje rezultaty poleceń realizowanych na bazie danych, z którą się łączymy. Co do zasady, w języku VBA, wszystkie operacje wykonywane na bazie danych są wykonywane "online" w trakcie trwania połączenia z bazą (czyli mówiąc wprost: po użyciu metody .Open i przed .Close). Nie mamy do dyspozycji obiektów, które potrafią np. odczytać i przechować zawartość, w celu jej edycji i późniejszego zapisania z powrotem do bazy: wszelkie operacje odbywają się w czasie rzeczywistym.
Obiektu Recordset używamy najczęściej wówczas, kiedy musimy z bazy danych odczytać określone informacje.

Najczęstszym przypadkiem wykorzystania tego obiektu będzie odczyt rekordów pobranych z bazy danych w wyniku użycia instrukcji SQL typu SELECT. Załóżmy, że chcielibyśmy z serwera SQL Server z bazy danych o nazwie "dane_import" wygenerować zawartość tabeli o tej samej nazwie. Polecenie SQL miałoby taką postać:

To samo polecenie przełożone na język VBA pod Excel musielibyśmy przekazać używając metody .Open dla wcześniej zdefiniowanego obiektu typu Recordset. Całość wyglądałaby następująco:

Sub pobieranie_danych()

'definiujemy odpowiednie zmienne ADODB
Dim cn As ADODB.Connection
Dim rst As ADODB.Recordset

'tworzymy rerefencje do obiektów:
Set cn = New ADODB.Connection
Set rst = New ADODB.Recordset

'łączymy się ze źródełm danych:
cn.Open "Provider=SQLOLEDB;Data Source='10.10.10.1';Initial Catalog='moja_baza';User ID='admin';Password='haslo'"

'wykonujemy polecenie SQL typu SELECT:
rst.Open "SELECT * FROM dane_import", cn

'uwalniamy zasoby komputera
Set rst = Nothing

'zamykamy połączenie z bazą:
cn.Close

End Sub

Sub pobieranie_danych()

'definiujemy odpowiednie zmienne ADODB
Dim cn As ADODB.Connection
Dim rst As ADODB.Recordset

'tworzymy rerefencje do obiektów:
Set cn = New ADODB.Connection
Set rst = New ADODB.Recordset

'łączymy się ze źródełm danych:
cn.Open "Provider=SQLOLEDB;Data Source='10.10.10.1';Initial Catalog='moja_baza';User ID='admin';Password='haslo'"

'wykonujemy polecenie SQL typu SELECT:
rst.Open "dane_import", cn

'uwalniamy zasoby komputera
Set rst = Nothing

'zamykamy połączenie z bazą:
cn.Close

End Sub

Pokazujemy ją, aby łatwiej było nam zrozumieć kolejne kroki, omawiające jak z obiektu typu Recordset wyciągnąć konkretne dane. Zmienna "rst" po wykonaniu powyższych poleceń zawiera właśnie taki zestaw informacji, jak przedstawiony na powyższym obrazie. Gdybyśmy chcieli ograniczyć zestaw danych, musielibyśmy rozszerzyć polecenie SELECT o klauzulę WHERE. Innymi słowy, aby ograniczyć liczbę wierszy (rekordów), które zostaną zwrócone w wyniku wykonania instrukcji SELECT musimy zmodyfikować polecenie SQL, gdyż później operacje wyszukiwania w obiekcie typu Recordset są o wiele bardziej skomplikowane, a przede wszystkim wymagają o wiele większej ilości zasobów lokalnego komputera (ponieważ to on musiałby przeglądać kolejno uzyskane rekordy, zamiast tak jak być powinno przekazać odpowiednie polecenia do bazy danych). Przykładowo, w sytuacji gdybyśmy chcieli wybrać z powyższej tabeli jedynie rekordy, które dotyczą produktu "Produkt 1" nasze polecenie wyglądałoby następująco:

a po przełożeniu na język VBA, nasze dotychczasowe polecenie, zmieniłoby kształt na następujący (przy wszystkich pozostałych elementach kodu programu bez zmian - od tego miejsca do końca rozdziału modyfikujemy tylko fragment kodu zawarty pomiędzy komentarzami: "wykonujemy polecenie SQL typu SELECT:" oraz "uwalniamy zasoby komputera:"):

'wykonujemy polecenie SQL typu SELECT:
rst.Open "SELECT * FROM dane_import WHERE produkt='Produkt 1'", cn

'wykonujemy polecenie SQL typu SELECT:
rst.Open "SELECT * FROM dane_import WHERE produkt='" & Sheets("Arkusz 1").Cells(1, 1) & "'", cn

'wykonujemy polecenie SQL typu SELECT:
rst.Open "SELECT * FROM dane_import WHERE miesiac=1", cn

'wykonujemy polecenie SQL typu SELECT:
rst.Open "SELECT * FROM dane_import WHERE miesiac=" & Sheets("Arkusz 1").Cells(1, 1), cn

'wykonujemy polecenie SQL typu SELECT:
rst.Open "SELECT * FROM dane_import", cn

licznik = 1

rst.MoveFirst

Do Until rst.EOF = True

	Cells(licznik, 1) = rst("nazwa_klienta").Value
	Cells(licznik, 2) = rst("produkt").Value
	Cells(licznik, 3) = rst("rok").Value
	Cells(licznik, 4) = rst("miesiac").Value
	Cells(licznik, 5) = rst("ilosc").Value
	Cells(licznik, 6) = rst("cena").Value
	Cells(licznik, 7) = rst("wartosc").Value

	licznik = licznik + 1
	rst.MoveNext
	
Loop

'wykonujemy polecenie SQL typu SELECT:
rst.Open "SELECT * FROM dane_import", cn

licznik = 1

rst.MoveFirst

Do Until rst.EOF = True

	For licznik2 = 0 To 6

		Cells(licznik, licznik2 + 1) = rst(licznik2).Value
	
	Next licznik2

	licznik = licznik + 1
	rst.MoveNext
	
Loop

'wykonujemy polecenie SQL typu SELECT:
rst.Open "SELECT * FROM dane_import", cn

Sheets("Arkusz 1").Cells(1, 1).CopyFromRecordset rst